// Basic New Keynesian Model with Standard Taylor Rule
//NKM.dyn
 
var 
x,   //  1.Output Gap
pi,  //  2.Inflation
i,   //  3.Nominal interest rate 
r,   //  4.Real interest rate
v,   //  5.Policy shock
u;   //  6.Cost Push Shock


varexo e_v,e_u; // policy, and inflation shocks

parameters
beta,   // Subjective discount factor
eta,    // Labor supply coef. in utility function
sigma,  // Consumption index coef. in utility function
omega,  // Calvo parameter (Fraction of firms not adjusting prices)
kappa,  // Inflation elasticity w.r.t output gap
phi_pi, // Taylor Rule Coef. on inflation  
phi_x,  // Taylor Rule Coef. on output-gap 
rho_v   // Policy Shock persistance
rho_u,  // Cost push shock persistance
sde_v   // Standard deviation for policy shock
sde_u;  // Stadard deviation for cost push shock

// parameter values
beta   = 0.99;
eta    = 1.0; 
sigma  = 1.0;
omega  = 0.8;
phi_pi = 1.5;
phi_x  = 0; //.5/4;
rho_v  = 0.5;
rho_u  = 0.9;
sde_v  = 0.01;
sde_u  = 0.002;

// Implied Parameters
kappa = (sigma + eta)*(1-omega)*(1-omega*beta)/omega;

model(linear);

x = x(+1) - (1/sigma)*( i - pi(+1) );   // IS curve
pi = beta*pi(+1) + kappa*x + u;         // New Keynesian Phillips curve
i = phi_pi*pi + phi_x*x + v ;           // Taylor Rule
r = i - pi(+1);                         // Real interest rate
v = rho_v*v(-1) + e_v;
u = rho_u*u(-1) + e_u;  
 
end;

steady;
check;

shocks; 
var e_v = 1; //(sde_v)^2;
var e_u = 1; //(sde_u)^2;
end;


/////////////////////////////////////////
// Computing Theoretical Moments and IRF's
////////////////////////////////////////
stoch_simul(order=1,ar=1,irf=20,nograph,noprint);
OOPT.MODELS.ooNKM =   oo_;
save OOPT_NKM;